mirror of
https://github.com/Llewellynvdm/conky.git
synced 2024-11-17 10:35:10 +00:00
c6ad28074a
* Include the XML schemas/libs in the repo so we don't have to reach out to 3rd parties * Fix the sed commands to work on both GNU and BSD variants
223 lines
7.9 KiB
XML
223 lines
7.9 KiB
XML
<?xml version='1.0'?>
|
|
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
|
|
xmlns:sverb="http://nwalsh.com/xslt/ext/com.nwalsh.saxon.Verbatim"
|
|
xmlns:xverb="xalan://com.nwalsh.xalan.Verbatim"
|
|
xmlns:lxslt="http://xml.apache.org/xslt"
|
|
exclude-result-prefixes="sverb xverb lxslt"
|
|
version='1.0'>
|
|
|
|
<!-- ********************************************************************
|
|
$Id: callout.xsl 9305 2012-04-27 21:50:53Z bobstayton $
|
|
********************************************************************
|
|
|
|
This file is part of the XSL DocBook Stylesheet distribution.
|
|
See ../README or http://docbook.sf.net/release/xsl/current/ for
|
|
copyright and other information.
|
|
|
|
******************************************************************** -->
|
|
|
|
<lxslt:component prefix="xverb"
|
|
functions="insertCallouts"/>
|
|
|
|
<xsl:template match="programlistingco|screenco">
|
|
<xsl:variable name="verbatim" select="programlisting|screen"/>
|
|
|
|
<xsl:choose>
|
|
<xsl:when test="$use.extensions != '0'
|
|
and $callouts.extension != '0'">
|
|
<xsl:variable name="rtf">
|
|
<xsl:apply-templates select="$verbatim">
|
|
<xsl:with-param name="suppress-numbers" select="'1'"/>
|
|
</xsl:apply-templates>
|
|
</xsl:variable>
|
|
|
|
<xsl:variable name="rtf-with-callouts">
|
|
<xsl:choose>
|
|
<xsl:when test="function-available('sverb:insertCallouts')">
|
|
<xsl:copy-of select="sverb:insertCallouts(areaspec,$rtf)"/>
|
|
</xsl:when>
|
|
<xsl:when test="function-available('xverb:insertCallouts')">
|
|
<xsl:copy-of select="xverb:insertCallouts(areaspec,$rtf)"/>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<xsl:message terminate="yes">
|
|
<xsl:text>No insertCallouts function is available.</xsl:text>
|
|
</xsl:message>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:variable>
|
|
|
|
<xsl:choose>
|
|
<xsl:when test="$verbatim/@linenumbering = 'numbered'
|
|
and $linenumbering.extension != '0'">
|
|
<div>
|
|
<xsl:call-template name="common.html.attributes"/>
|
|
<xsl:call-template name="id.attribute"/>
|
|
<xsl:call-template name="number.rtf.lines">
|
|
<xsl:with-param name="rtf" select="$rtf-with-callouts"/>
|
|
<xsl:with-param name="pi.context"
|
|
select="programlisting|screen"/>
|
|
</xsl:call-template>
|
|
<xsl:apply-templates select="calloutlist"/>
|
|
</div>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<div>
|
|
<xsl:call-template name="common.html.attributes"/>
|
|
<xsl:call-template name="id.attribute"/>
|
|
<xsl:copy-of select="$rtf-with-callouts"/>
|
|
<xsl:apply-templates select="calloutlist"/>
|
|
</div>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<div>
|
|
<xsl:apply-templates select="." mode="common.html.attributes"/>
|
|
<xsl:call-template name="id.attribute"/>
|
|
<xsl:apply-templates/>
|
|
</div>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:template>
|
|
|
|
<xsl:template match="areaspec|areaset|area">
|
|
</xsl:template>
|
|
|
|
<xsl:template match="areaset" mode="conumber">
|
|
<xsl:number count="area|areaset" format="1"/>
|
|
</xsl:template>
|
|
|
|
<xsl:template match="area" mode="conumber">
|
|
<xsl:number count="area|areaset" format="1"/>
|
|
</xsl:template>
|
|
|
|
<xsl:template match="co" name="co">
|
|
<!-- Support a single linkend in HTML -->
|
|
<xsl:variable name="targets" select="key('id', @linkends)"/>
|
|
<xsl:variable name="target" select="$targets[1]"/>
|
|
<xsl:choose>
|
|
<xsl:when test="$target">
|
|
<a>
|
|
<xsl:apply-templates select="." mode="common.html.attributes"/>
|
|
<xsl:choose>
|
|
<xsl:when test="$generate.id.attributes = 0">
|
|
<!-- force an id attribute here -->
|
|
<xsl:if test="@id or @xml:id">
|
|
<xsl:attribute name="name">
|
|
<xsl:value-of select="(@id|@xml:id)[1]"/>
|
|
</xsl:attribute>
|
|
</xsl:if>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<xsl:call-template name="id.attribute"/>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
<xsl:attribute name="href">
|
|
<xsl:call-template name="href.target">
|
|
<xsl:with-param name="object" select="$target"/>
|
|
</xsl:call-template>
|
|
</xsl:attribute>
|
|
<xsl:apply-templates select="." mode="callout-bug"/>
|
|
</a>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<xsl:if test="$generate.id.attributes != 0">
|
|
<xsl:if test="@id or @xml:id">
|
|
<span>
|
|
<xsl:attribute name="id">
|
|
<xsl:value-of select="(@id|@xml:id)[1]"/>
|
|
</xsl:attribute>
|
|
</span>
|
|
</xsl:if>
|
|
</xsl:if>
|
|
<xsl:call-template name="anchor"/>
|
|
<xsl:apply-templates select="." mode="callout-bug"/>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:template>
|
|
|
|
<xsl:template match="coref">
|
|
<!-- tricky; this relies on the fact that we can process the "co" that's -->
|
|
<!-- "over there" as if it were "right here" -->
|
|
|
|
<xsl:variable name="co" select="key('id', @linkend)"/>
|
|
<xsl:choose>
|
|
<xsl:when test="not($co)">
|
|
<xsl:message>
|
|
<xsl:text>Error: coref link is broken: </xsl:text>
|
|
<xsl:value-of select="@linkend"/>
|
|
</xsl:message>
|
|
</xsl:when>
|
|
<xsl:when test="local-name($co) != 'co'">
|
|
<xsl:message>
|
|
<xsl:text>Error: coref doesn't point to a co: </xsl:text>
|
|
<xsl:value-of select="@linkend"/>
|
|
</xsl:message>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<xsl:apply-templates select="$co"/>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:template>
|
|
|
|
<xsl:template match="co" mode="callout-bug">
|
|
<xsl:call-template name="callout-bug">
|
|
<xsl:with-param name="conum">
|
|
<xsl:number count="co"
|
|
level="any"
|
|
from="programlisting|screen|literallayout|synopsis"
|
|
format="1"/>
|
|
</xsl:with-param>
|
|
</xsl:call-template>
|
|
</xsl:template>
|
|
|
|
<xsl:template name="callout-bug">
|
|
<xsl:param name="conum" select='1'/>
|
|
|
|
<xsl:choose>
|
|
<xsl:when test="$callout.graphics != 0
|
|
and $conum <= $callout.graphics.number.limit">
|
|
<!-- Added span to make valid in XHTML 1 -->
|
|
<span><img src="{$callout.graphics.path}{$conum}{$callout.graphics.extension}"
|
|
alt="{$conum}" border="0"/></span>
|
|
</xsl:when>
|
|
<xsl:when test="$callout.unicode != 0
|
|
and $conum <= $callout.unicode.number.limit">
|
|
<xsl:choose>
|
|
<xsl:when test="$callout.unicode.start.character = 10102">
|
|
<xsl:choose>
|
|
<xsl:when test="$conum = 1">❶</xsl:when>
|
|
<xsl:when test="$conum = 2">❷</xsl:when>
|
|
<xsl:when test="$conum = 3">❸</xsl:when>
|
|
<xsl:when test="$conum = 4">❹</xsl:when>
|
|
<xsl:when test="$conum = 5">❺</xsl:when>
|
|
<xsl:when test="$conum = 6">❻</xsl:when>
|
|
<xsl:when test="$conum = 7">❼</xsl:when>
|
|
<xsl:when test="$conum = 8">❽</xsl:when>
|
|
<xsl:when test="$conum = 9">❾</xsl:when>
|
|
<xsl:when test="$conum = 10">❿</xsl:when>
|
|
</xsl:choose>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<xsl:message>
|
|
<xsl:text>Don't know how to generate Unicode callouts </xsl:text>
|
|
<xsl:text>when $callout.unicode.start.character is </xsl:text>
|
|
<xsl:value-of select="$callout.unicode.start.character"/>
|
|
</xsl:message>
|
|
<xsl:text>(</xsl:text>
|
|
<xsl:value-of select="$conum"/>
|
|
<xsl:text>)</xsl:text>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<xsl:text>(</xsl:text>
|
|
<xsl:value-of select="$conum"/>
|
|
<xsl:text>)</xsl:text>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:template>
|
|
|
|
</xsl:stylesheet>
|